KI-97: IPP Homepage

Syntax of Operator Files for RIPP 0.1 with Resources

The operator file contains the set of operators that may be applied in the planning domain. It must be a text file having an arbitrary name. IPP will try to apply all the ops which are contained in it, i.e., you need to put different operator sets into different files.

Basic Name Conventions:

Type names are arbitary strings of small and capital letters, the numbers 0-9, underscores and dashes. Valid typenames are for example 111, p-11, G09-7_b1.
Variable names start with "?" followed by an arbitrary string of small and capital letters, the numbers 0-9, dashes and brackets "[" and "]".
Resource-variable names start with "$" followed by an arbitrary string of small and capital letters, the numbers 0-9, and dashes. Then braces "(" ")" must follow, which can contain variable or constant names in arbitrary order as arguments. (terminalsymbol rvarname)
Predicate names are arbitary strings of small and capital letters, the numbers 0-9 and dashes. (terminalsymbol predicatename)
Constant names can contain small and capital letters, the numbers 0-9, dashes and brackets "[" and "]". (terminalsymbol constantname)
Numbers can have a minus sign and must always contain a dot ".", i.e. they are at least of the form digit "." digit. (terminalsymbol number)
Equality is represented using the distinguished predicate name "eq", for example "!eq(?x ?y)" means that the variables ?x and ?y must be different and "eq(c ?z)" means that the variable ?z must be equal to the constant c. (
The universal quantifier is represented with "ALL", negation with "!". (terminalsymbols ALL, !)
Comments start at the beginning of a line with a "#" and end with a newline. They can be put everywhere in a file.

Upper-case letters denote non-terminal symbols, lower-case letters denote terminal symbols. + means one or arbitrarily many occurrances of a symbol. * means zero or arbitrarily many occurrances of a symbol. [symbol] means optional occurrance.

OP_FILE      ::= /* empty */ 
                 |  OP OP_FILE

OP           ::=  constantname ":v"  PARDEC  ":p"  PRECONDS ":e"  EFFECTS
 
PARDEC       ::= /* empty */ 
                 | variablename* typename  PARDEC


PRECONDS     ::= /* empty */ 
                 | RESOURCE-REQ PRECONDS 
                 | FACT PRECONDS


FACT         ::= /* empty */ 
                 | [!] predicatename "(" NAMELIST ")"  
                 | [!] "eq" "(" varname varname ")"
                 | [!] "eq" "(" varname constname ")"


NAMELIST     ::= /* empty */
                 | constantname NAMELIST
                 | variablename NAMELIST


RESOURCE-REQ ::=   COMPAR "(" rvarname number ")"
                 | COMPAR "(" rvarname database ")"
                 | COMPAR "(" rvarname database OP number ")"



EFFECTS      ::= FACT* ";" COND-EFF QUANT-EFF RES-EFF "."
                 

COND-EFF     ::= /* empty */
                 | FACT+ "=>" FACT+  ";" COND-EFF

QUANT-EFF    ::= /* empty */
                 | ALL PARDEC FACT* "=>" FACT+ ";" QUANT-EFF 
                  

RES-EFF      ::= /* empty */
                 | rvarname ASSIGN number ";" RES-EFF 
                 | rvarname ASSIGN database ";" RES-EFF 
                 | rvarname ASSIGN database OP number ";" RES-EFF  
                 | rvarname ASSIGN number "*" rvarname "+" number  
                   ";" RES-EFF  
                   
COMPAR       ::= ">" | "=" | "<"
 
ASSIGN       ::= "+=" | "-=" | ":="

OP           ::= "+" | "-" | "*" | "/"

Effects are a possibly empty list of literals, followed by conditional non-quantified effects, followed by universally quantified conditional effects. The effect condition in quantified effects can be empty. Resource effects are listed last. The last effect must be followed by ".", not by ";." as the grammer suggests. No ADD and DEL effects are allowed anymore. If you have a predicate without any parameters, you still have to add the "()", as in arm-empty(). Names should not be longer than 256 characters. Equality and Disequality should never occur in effects. Examples of accepted operator files can be found in our domain collection.